home *** CD-ROM | disk | FTP | other *** search
/ Internet Info 1994 March / Internet Info CD-ROM (Walnut Creek) (March 1994).iso / networking / ip / ka9q / src.arc / PCGEN.ASM < prev    next >
Encoding:
Assembly Source File  |  1989-03-25  |  8.8 KB  |  456 lines
  1.     .MODEL    MEMMOD,C
  2.     LOCALS
  3.     %MACS
  4.     .LALL
  5.     extrn    ctick:proc
  6.  
  7. ; Hardware vector for timer linkage
  8. ; We use the timer hardware channel here instead of the indirect BIOS
  9. ; channel (1ch) because the latter is sluggish when running under DoubleDos
  10. TIMEVEC    EQU    08h
  11.  
  12.     .DATA
  13.     public    Intstk,Stktop,Spsave,Sssave
  14.     extrn    Isat:byte
  15. Spsave    dw    ?        ; Save location for SP during interrupts
  16. Sssave    dw    ?        ; Save location for SS during interrupts
  17. Intstk    dw    512 dup(?)    ; Interrupt working stack
  18. Stktop    equ    $        ; SP set here when entering interrupt
  19. mtasker    db    ?        ; Type of higher multitasker, if any
  20.  
  21.     .CODE
  22. dbase    dw    @Data
  23. jtable    dw    l0,l1,l2,l3,l4,l5,l6,l7,l8,l9,l10,l11,l12,l13,l14,l15    
  24.  
  25. ; common routine for interrupt return
  26.     public    doret
  27.     label    doret    far
  28.     cmp    Isat,1
  29.     jnz    @@1        ; Only one 8259, so skip this stuff
  30.     mov    al,0bh        ; read in-service register from
  31.     out    0a0h,al        ; secondary 8259
  32.     nop            ; settling delay
  33.     nop
  34.     nop
  35.     in    al,0a0h        ; get it
  36.     or    al,al        ; Any bits set?
  37.     jz    @@1        ; nope, not a secondary interrupt
  38.     mov    al,20h        ; Get EOI instruction
  39.     out    0a0h,al        ; Secondary 8259 (PC/AT only)
  40. @@1:    mov    al,20h        ; 8259 end-of-interrupt command
  41.     out    20h,al        ; Primary 8259
  42.     pop    es
  43.     pop    di
  44.     pop    si
  45.     pop    bp
  46.     pop    dx
  47.     pop    cx
  48.     pop    bx
  49.     pop    ax
  50.     mov    ss,Sssave
  51.     mov    sp,Spsave    ; restore original stack context
  52.     pop    ds
  53.     iret
  54.  
  55. ; Null interrupt handler
  56.     public    nullvec
  57. nullvec    proc
  58.     iret
  59. nullvec    endp
  60.  
  61. ; istate - return current interrupt state
  62.     public    istate
  63. istate    proc
  64.     pushf
  65.     pop    ax
  66.     and    ax,200h
  67.     jnz    @@1
  68.     ret
  69. @@1:    mov    ax,1
  70.     ret
  71. istate    endp
  72.  
  73. ; dirps - disable interrupts and return previous state: 0 = disabled,
  74. ;           1 = enabled
  75.     public dirps
  76. dirps    proc
  77.     pushf            ; save state on stack
  78.     cli            ; interrupts off
  79.     pop    ax        ; original flags -> ax
  80.     and    ax,200h        ; 1<<9 is IF bit
  81.     jnz    @@1        ; nonzero -> interrupts were on
  82.     ret
  83. @@1:    mov    ax,1
  84.     ret
  85. dirps    endp
  86.  
  87. ; restore - restore interrupt state: 0 = off, nonzero = on
  88.     public    restore
  89. restore    proc
  90.     arg is:word
  91.     test    is,0ffffh
  92.     jz    @@1
  93.     sti
  94.     ret
  95. @@1:    cli
  96.     ret
  97. restore    endp
  98.  
  99. ; multitasker types
  100. NONE        equ    0
  101. DOUBLEDOS    equ    1
  102. DESQVIEW    equ    2
  103.  
  104. ; Relinquish processor so other task can run
  105.     public    giveup
  106. giveup    proc
  107.     pushf        ;save caller's interrupt state
  108.     sti        ;re-enable interrupts
  109.     cmp    mtasker, DOUBLEDOS
  110.     jnz    @@1
  111.     mov    al,2        ; 110 ms
  112.     mov    ah,0eeh
  113.     int    21h
  114.     popf        ; restore interrupts
  115.     ret
  116.  
  117. @@1:    cmp    mtasker, DESQVIEW
  118.     jnz    @@2
  119.     mov    ax, 1000h
  120.     int    15h
  121.     popf        ; restore interrupts
  122.     ret
  123.  
  124. @@2:    hlt        ; wait for an interrupt
  125.     popf        ; restore interrupts
  126.     ret
  127. giveup    endp
  128.  
  129. ; check for a multitasker running
  130.     public    chktasker
  131. chktasker    proc
  132.     mov    mtasker,NONE
  133.     ; do the doubledos test
  134.     mov    ah,0e4h
  135.     int    21h
  136.     cmp    al,1
  137.     jz    @@1
  138.     cmp    al,2
  139.     jnz    @@2
  140. @@1:    mov    mtasker, DOUBLEDOS
  141.     ret
  142.  
  143.     ; test for desqview
  144. @@2:    mov    ax, 2b01h
  145.     mov    cx, 4445h
  146.     mov    dx, 5351h
  147.     int    21h
  148.     cmp    al, 0ffh
  149.     jnz    @@3
  150.     ret
  151.  
  152. @@3:    mov    mtasker, DESQVIEW
  153.     ret
  154. chktasker    endp
  155.  
  156. ; getss - Read SS for debugging purposes
  157.     public    getss
  158. getss    proc
  159.     mov    ax,ss
  160.     ret
  161. getss    endp
  162.  
  163. ; Internet checksum subroutine
  164. ; Compute 1's-complement sum of data buffer
  165. ; Uses an unwound loop inspired by "Duff's Device" for performance
  166. ;
  167. ; Called from C as
  168. ; unsigned short
  169. ; lcsum(buf,cnt)
  170. ; unsigned short *buf;
  171. ; unsigned short cnt;
  172.     public    lcsum
  173. lcsum    proc
  174.     arg    buf:ptr,cnt:word
  175.  
  176.     if    @Datasize NE 0
  177.         uses    ds,si
  178.         lds    si,buf    ; ds:si = buf
  179.     else
  180.         uses    si
  181.         mov    si,buf    ; ds:si = buf (ds already set)
  182.     endif
  183.  
  184.     mov    cx,cnt        ; cx = cnt
  185.     cld            ; autoincrement si
  186.     mov    ax,cx
  187.     shr    cx,1        ; cx /= 16, number of loop iterations
  188.     shr    cx,1
  189.     shr    cx,1
  190.     shr    cx,1
  191.  
  192.     inc    cx        ; make fencepost adjustment for 1st pass
  193.     and    ax,15        ; ax = number of words modulo 16
  194.     shl    ax,1        ; *=2 for word table index
  195.     lea    bx,jtable    ; bx -> branch table
  196.     add    bx,ax        ; index into jump table
  197.     clc            ; initialize carry = 0
  198.     mov    dx,0        ; clear accumulated sum
  199.     jmp    word ptr cs:[bx]    ; jump into loop
  200.  
  201. ; Here the real work gets done. The numeric labels on the lodsw instructions
  202. ; are the targets for the indirect jump we just made.
  203. ;
  204. ; Each label corresponds to a possible remainder of (count / 16), while
  205. ; the number of times around the loop is determined by the quotient.
  206. ;
  207. ; The loop iteration count in cx has been incremented by one to adjust for
  208. ; the first pass.
  209. ; 
  210. deloop:    lodsw
  211.     adc    dx,ax
  212. l15:    lodsw
  213.     adc    dx,ax
  214. l14:    lodsw
  215.     adc    dx,ax
  216. l13:    lodsw
  217.     adc    dx,ax
  218. l12:    lodsw
  219.     adc    dx,ax
  220. l11:    lodsw
  221.     adc    dx,ax
  222. l10:    lodsw
  223.     adc    dx,ax
  224. l9:    lodsw
  225.     adc    dx,ax
  226. l8:    lodsw
  227.     adc    dx,ax
  228. l7:    lodsw
  229.     adc    dx,ax
  230. l6:    lodsw
  231.     adc    dx,ax
  232. l5:    lodsw
  233.     adc    dx,ax
  234. l4:    lodsw
  235.     adc    dx,ax
  236. l3:    lodsw
  237.     adc    dx,ax
  238. l2:    lodsw
  239.     adc    dx,ax
  240. l1:    lodsw
  241.     adc    dx,ax
  242. l0:    loop    deloop        ; :-)
  243.  
  244.     adc    dx,0        ; get last carries
  245.     adc    dx,0
  246.     mov    ax,dx        ; result into ax
  247.     xchg    al,ah        ; byte swap result (8088 is little-endian)
  248.     ret
  249. lcsum    endp
  250.  
  251. ; Link timer handler into timer chain
  252. ; Arg == address of timer handler routine
  253. ; MUST be called exactly once before uchtimer is called!
  254.  
  255. toff    dw    ?        ; save location for old vector
  256. tseg    dw    ?        ;  must be in code segment
  257.  
  258.     public    chtimer
  259. chtimer    proc
  260.     arg    vec:far ptr
  261.     uses    ds
  262.  
  263.     mov    ah,35h        ; get current vector
  264.     mov    al,TIMEVEC
  265.     int    21h        ; puts vector in es:bx
  266.     mov    cs:tseg,es    ; stash
  267.     mov    cs:toff,bx
  268.  
  269.     mov    ah,25h
  270.     mov    al,TIMEVEC
  271.     lds    dx,vec        ; ds:si = vec
  272.  
  273.     int    21h        ; set new vector
  274.     ret
  275. chtimer    endp
  276.  
  277. ; unchain timer handler from timer chain
  278. ; MUST NOT be called before chtimer!
  279.     public    uchtimer
  280. uchtimer    proc
  281.     uses    ds
  282.  
  283.     mov    ah,25h
  284.     mov    al,TIMEVEC
  285.     mov    dx,toff
  286.     mov    ds,tseg
  287.     int    21h        ; restore old vector
  288.     ret
  289. uchtimer    endp
  290.  
  291. ; Clock tick interrupt handler. Note the use of "label" rather than "proc"
  292. ; here, necessitated by the fact that "proc" automatically generates BP-saving
  293. ; code that we don't want here.
  294.  
  295.     public    btick
  296.     label    btick    far
  297.  
  298.     pushf
  299.     push    ds
  300.     cli
  301.     mov    ds,cs:dbase    ; establish interrupt data segment
  302.  
  303.     mov    Sssave,ss    ; stash user stack context
  304.     mov    Spsave,sp
  305.  
  306.     mov    ss,cs:dbase
  307.     lea    sp,Stktop
  308.  
  309.     push    ax        ; save user regs on interrupt stack
  310.     push    bx
  311.     push    cx
  312.     push    dx
  313.     push    bp
  314.     push    si
  315.     push    di
  316.     push    es
  317.  
  318.     call    ctick
  319.  
  320.      pop    es
  321.     pop    di
  322.     pop    si
  323.     pop    bp
  324.     pop    dx
  325.     pop    cx
  326.     pop    bx
  327.     pop    ax
  328.     mov    ss,Sssave
  329.     mov    sp,Spsave    ; restore original stack context
  330.     pop    ds
  331.     popf
  332.     jmp    dword ptr [toff]        ; link to previous vector
  333.  
  334. ; Convert 32-bit int in network order to host order (dh, dl, ah, al)
  335. ; Called from C as
  336. ; int32 get32(char *cp);
  337.  
  338.     public    get32
  339. get32    proc
  340.     arg    cp:ptr
  341.     if    @Datasize NE 0
  342.         uses    ds,si
  343.         lds    si,cp    ; ds:si = cp
  344.     else
  345.         uses    si
  346.         mov    si,cp    ; ds:si = cp (ds already set)
  347.     endif
  348.  
  349.     cld
  350.     lodsw
  351.     mov    dh,al    ; high word to dx, a-swapping as we go
  352.     mov    dl,ah
  353.     lodsw
  354.     xchg    al,ah    ; low word stays in ax, just swap
  355.     ret
  356. get32    endp
  357.  
  358. ; Convert 16-bit int in network order to host order (ah, al)
  359. ; Called from C as
  360. ; int16 get16(char *cp);
  361.  
  362.     public    get16
  363. get16    proc
  364.     arg    cp:ptr
  365.     if    @Datasize NE 0
  366.         uses    ds,si
  367.         lds    si,cp    ; ds:si = cp
  368.     else
  369.         uses    si
  370.         mov    si,cp    ; ds:si = cp (ds already set)
  371.     endif
  372.  
  373.     cld
  374.     lodsw
  375.     xchg    al,ah    ; low word stays in ax, just swap
  376.     ret
  377. get16    endp
  378.  
  379. ; Convert 32-bit int to network order, returning new pointer
  380. ; Called from C as
  381. ; char *put32(char *cp,int32 x);
  382.  
  383.     public    put32
  384. put32    proc
  385.     arg    cp:ptr,x:dword
  386.     if    @Datasize NE 0
  387.         uses    ds,di,si
  388.         les    di,cp    ; es:di = cp
  389.         mov    ax,ss    ; our parameter is on the stack, and ds might not
  390.         mov    ds,ax    ;   be pointing to ss.
  391.     else
  392.         uses    di,si
  393.         mov    di,cp    ; es:di = cp
  394.         mov    ax,ds    ; point es at data segment
  395.         mov    es,ax
  396.     endif
  397.  
  398.     cld
  399.     lea    si,x    ; point si to input doubleword
  400.     lodsw        ; fetch low word of machine version
  401.     mov    dh,al    ; swap bytes and save
  402.     mov    dl,ah
  403.     lodsw        ; fetch high word
  404.     xchg    ah,al    ; byte swap
  405.     stosw        ; store in output
  406.     mov    ax,dx    ; retrieve low word and store in output
  407.     stosw
  408.     mov    ax,di    ; return incremented output pointer
  409.     if    @Datasize NE 0
  410.         mov    dx,es    ; upper half of pointer
  411.     endif
  412.     ret
  413. put32    endp
  414.  
  415. ; Convert 16-bit int to network order, returning new pointer
  416. ; Called from C as
  417. ; char *put16(char *cp,int16 x);
  418.  
  419.     public    put16
  420. put16    proc
  421.     arg    cp:ptr,x:word
  422.     uses    di,si
  423.     if    @Datasize NE 0
  424.         les    di,cp    ;es:di = cp
  425.     else
  426.         mov    di,cp    ; es:di = cp
  427.         mov    ax,ds
  428.         mov    es,ax
  429.     endif
  430.     cld
  431.     mov    ax,x    ; fetch source word in machine order
  432.     xchg    ah,al    ; swap bytes
  433.     stosw        ; save in network order
  434.     mov    ax,di    ; return new output pointer to user
  435.     if    @Datasize NE 0
  436.         mov    dx,es    ; upper half of pointer
  437.     endif
  438.     ret
  439. put16    endp
  440.  
  441. ; kbraw - raw, nonblocking read from console
  442. ; If character is ready, return it; if not, return -1
  443.     public    kbraw
  444. kbraw    proc
  445.     mov    ah,06h    ; Direct Console I/O
  446.     mov    dl,0ffh    ; Read from keyboard
  447.     int    21h    ; Call DOS
  448.     jz    @@1    ; zero flag set -> no character ready
  449.     mov    ah,0    ; valid char is 0-255
  450.     ret
  451. @@1:    mov    ax,-1    ; no char, return -1
  452.     ret
  453. kbraw    endp
  454.  
  455.     end
  456.